NOTE by T. Utsumi on 3/3rd/2004:
The following model has not been executed, and may still has OCR error.

$$$CONTINUOUS SYSTEM MODELING PROGRAM  III   V1MO   TRANSLATOR OUTPUT$$$
*
*--------------------------------------------------------------------------------
*
TITLE CSMP-III SIMULATION OF WORLD DYNAMICS-2
TITLE T. UTSUMI AND Y. SHINDOU
TITLE MITSUBISHI RESEARCH INSTITUTE
TITLE 1-6-E, OHTEMACHI, CHIYODAKU, TOKYO, 100. PHONE (03)-214-5531
*
*--------------------------------------------------------------------------------
* 1.  INTRODUCTION
*--------------------------------------------------------------------------------
*                                                                            6060
*     THIS WORLD DYNAMICS MODEL WAS FIRST CONSTRUCTED BY J. FORRESTER
*     OF MASSACHUSETTS INSTITUTE OF TECHNOLOGY.
*     THOUGH THE ORIGINAL MODEL WAS WRITTEN IN DYNAMO LANGUAGE,
*     THE MODEL, WHEN IT WAS OBTAINED FROM J.MCLEOD OF SIMULATION COUNCILS, INC.,
*     WAS CCNVERTED TO BASIC LANGUAGE.
*     THEN, THIS MODEL IN BASIC LANGUAGE WAS ONCE AGAIN
*     CONVERTED INTO CSMP-III LANGUAGE BY YUJI SHINDOU IN JULY, 1972.
*                                                                           10100
*     (REFERENCE - FORRESTER, JAY W., "WORLD DYNAMICS"  )
*     (            WRIGHT-ALLEN PPESS, INC.             )
*     (            231 MAIN STREET                      )
*     (            CAMBRIDGE, MASSACHUSETTS, 02142      )
*
*********************************************************************************
*********************************************************************************
INITIAL SEGMENT                                                              1600
*********************************************************************************
*********************************************************************************
*                                                                            1950
*--------------------------------------------------------------------------------
* 2. INITIAL CONDITION OF MODEL
*--------------------------------------------------------------------------------
*                                                                            7250
INCON CII   =   0.4000E+09, CIAFI = 0.2000E+00,...
      NRI   = 900.0000E+09, PI    = 1.6500E+09,...
      POLI  =   0.2000E+09
*                                                                            2950
*     ------------------------------------------------------------------
*                                                                            9200
*     CII   = CAPITAL INVESTMENT,  INITIAL (CAPITAL UNITS)                   3900
*     CIAFI = CAPITAL-INVESTMENT-IN-AGRICULTURE FRACTION,  INITIAL           2500
*                  (DIMENSIONLESS)                                           2600
*     NRI   = NATURAL RESOURCE,  INITIAL (NATURAL RESOURCE UNITS)            7800
*     PI    = POPULATION,  INITIAL (PEOPLE)                                  8800
*     POLI  = POLLUTION,  INITIAL (POLLUTION UNITS)                          9600
*                                                                           23900
*********************************************************************************
*********************************************************************************
DYNAMIC SEGMENT                                                              4400
*********************************************************************************
*********************************************************************************
*                                                                            4700
RENAME   TIME = T                                                            1800
*
*     ------------------------------------------------------------------
*                                                                            5500
*     T     = CALENDAR TIME (YEARS)                                         11800
*
*--------------------------------------------------------------------------------
* 3.  POPULATION (P)
*--------------------------------------------------------------------------------
* 3.1 POPULATION (P)
*--------------------------------------------------------------------------------
*                                                                            8250
*     (SECTION 3.1 OF REFERENCE)
*                                                                            7050
*     POPULATION P IS A SYSTEM "LEVEL" VARIABLE. A SYSTEM LEVEL RE-           100
*     PRESENTS THE PROCESS OF ACCUMULATION.  LEVELS PROVIDE THE SYSTEM        200
*     "MEMORY" OR CCNTINUITY THAT CARRIES THE PAST INTO THE FUTURE.           300
*
*     POPULATION AT ANY TIME IS CALCULATED AS THE POPULATION AT THE           400
*     PRECEDING POINT IN TIME, PLUS THE PEOPLE WHO HAVE BEEN ADDED BY         500
*     THE BIRTH RATE (BR) IN THE INTERVENING INTERVAL, MINUS THE PEOPLE
*     REMOVED BY THE DEATH RATE (DR).
*                                                                            5810
*     ------------------------------------------------------------------
*                                                                           14500
      P     = INTGRL(PI,BR-DR)                                               5850
*                                                                           10300
*     ------------------------------------------------------------------
*                                                                           10300
*     P     = POPULATION (PEOPLE)                                            8600
*     BR    = BIRTH RATE (PEOPLE/YEAR)
*     DR    = DEATH RATE (PEOPLE/YEAR)
*                                                                            7700
*--------------------------------------------------------------------------------
* 3.2 BIRTH RATE (BR)
*--------------------------------------------------------------------------------
*
*     (SECTION 3.2, 3.3, 3.16, 3.17, 3.18 OF REFERENCE)
*                                                                           10100
*     BAS1C BIRTH RATE DEPENDS ON POPULATION (P) AND ON A COEFFICIENT (BRN).
*     BUT THE ACTUAL BIRTH RATE WILL DEPEND ON THE CONDITIONS OF CAPITAL
*     INVESTMENT (CI) AND NATURAL RESOURCES (NR) AS THEY MANIFEST THEMSELVES
*     IN MATERIAL STANDARD OF LIVING (MSL), ON CROWDING, ON FOOD AVAILABILITY,
*     AND ON POLLUTION.
*
*     ------------------------------------------------------------------
*
*     BR    = P*BRNT1*BRFM*BRMM*BRCM*BRPM
      BRCM  = AFGEN( BRCMT,   CRX)                                           1300
      BRFM  = AFGEN( BRFMT,   FRX)                                           1100
      BRMM  = AFGEN( BRMMT,  MSLX)                                           1200
      BRNT1 = FCNSW(SWT1-T,BRN1,BRN1,BRN)
      BRPM  = AFGEN( BRPMT, POLRX)                                           1400
*                                                                           12200
*     ------------------------------------------------------------------
*
PARAMETER  BRN   =   0.0400E+00, BRN1  =    0.0400E+00,...                   1900
           SWT1  = 197.0000E+01
*
FUNCTION  BRCMT = (  0.0 ,  1.05), (  1.0 ,   1.0 ), (  2.0 ,  0.9 ),...
                  (  3.0 ,  0.7 ), (  4.0 ,   0.6 ), (  5.0 ,  0.55)
FUNCTION  BRFMT = (  0.0 ,  0.0 ), (  1.0 ,   1.0 ), (  2.0 ,  1.6 ),...
                  (  3.0 ,  1.9 ), (  4.0 ,   2.0 )
FUNCTION  BRMMT = (  0.0 ,  1.2 ), (  1.0 ,   1.0 ), (  2.0 ,  0.85),...
                  (  3.0 ,  0.75), (  4.0 ,   0.7 ), (  5.0 ,  0.7 )
FUNCTION  BRPMT = (  0.0 ,  1.02), ( 10.0 ,   0.9 ), ( 20.0 ,  0.7 ),...
                  ( 30.0 ,  0.4 ), ( 40.0 ,   0.25), ( 50.0 ,  0.15),...
                  ( 60.0 ,  0.1 )
*                                                                            9650
*     ------------------------------------------------------------------
*                                                                           10250
*     BR    = BIRTH RATE (PEOPLE/YEAR)                                       1000
*     BRCM  = BIRTH-RATE-FROM-CROWDING MULTIPLIER (DIMENSIONLESS)            1100
*     BRCMT = BIRTH-RATE-FROM-CROWDING-MULTIPLIER TABLE                      1200
*     BRFM  = BIRTH-RATE-FROM-FOOD MULTIPLIER (DIMENSIONLESS)                1300
*     BRFMT = BIRTH-RATE-FROM-FOOD-MULTIPLIER TABLE                          1400
*     BRMM  = BIRTH-RATE-FROM-MATERIAL MULTIPLIER (DIMENSIONLESS)            1500
*     BRMMT = BIRTH-RATE-FROM-MATERIAL-MULTIPLIER TABLE                      1600
*     BRN   = BIRTH RATE NORMAL (FRACTION/YEAR)                              1700
*     BRN1  = BIRTH RATE NORMAL NO. 1 (FRACTION/YEAR)                        1800
*     BRNT1 = BRN1, IF(SWT1.LT.T)
*           = BRN1, IF(SWT1.EQ.T)
*           = BRN , IF(SWT1.GT.T)
*     BRPM  = BIRTH-PATE-FROM-POLLUTION MULTIPLIER (DIMENSIONLESS)           1900
*     BRPMT = BIRTH-PATE-FROM-POLLUTION-MULTIPLIER TABLE                     2000
*     SWT1  = SWITCH TIME NO. 1 FOR BRN (YEARS)                             11100
*                                                                            9550
*--------------------------------------------------------------------------------
* 3.3 DEATH RATE (DR)
*--------------------------------------------------------------------------------
*                                                                           10200
*     (SECTION 3.10, 3.11, 3.12, 3.13, 3.14 OF REFERENCE)
*                                                                            9850
*     BASIC DEATH RATE IS POPULATION (P) MULTIPLIED BY THE DEATH RATE NORMAL
*     (DRN), BUT THE ACTUAL DEATH RATE, LIKE THE BIRTH RATE, DEPENDS ON
*     CONDITIONS IN OTHER PARTS OF THE WORLD SYSTEM, THAT IS FOOD, CROWDING,
*     MATERIAL STANDARD OF LIVING, AND POLLUTION.
*
*     ------------------------------------------------------------------
*
      CR    = P*DRNT3*DRMM*DRPM*DRFM*DRCM
      DRCM  = AFGEN( DRCMT,   CRX)                                           2400
      DRFM  = AFGEN( DRFMT,   FRXX)                                          2300
      DRMM  = AFGEN( DRMMT,   MSLX)                                          2100
      DRNT3 = FCNSW(SWT3-T,DRN1,DRN1,DRN)
      DRPM  = AFGEN( DRPMT, POLRX)                                           2200
*
*     ------------------------------------------------------------------
*
PARAMETER  DRN   =   0.0280E+00, DRN1  =   0.0280E+00,...                    2500
           SWT3  = 197.0000E+01
*                                                                           10150
FUNCTION  DRCMT = (  0.0 ,  0.9 ), (  1.0 ,  1.0 ), (  2.0 ,  1.2 ),...
                  (  3.0 ,  1.5 ), (  4.0 ,  1.9 ), (  5.0 ,  3.0 )
FUNCTION  DRFMT = (  0.0 , 30.0 ), (  0.25,  3.0 ), (  0.5 ,  2.0 ),...
                  (  0.75,  1.4 ), (  1.0 ,  1.0 ), (  1.25,  0.7 ),...
                  (  1.5 ,  0.6 ), (  1.75,  0.5 ), (  2.0 ,  0.5 )
FUNCTION  DRMMT = (  0.0 ,  3.0 ), (  0.5 ,  1.8 ), (  1.0 ,  1.0 ),...
                  (  1.5 ,  0.8 ), (  2.0 ,  0.7 ), (  2.5 ,  0.6 ),...
                  (  3.0 ,  0.53), (  3.5 ,  0.5 ), (  4.0 ,  0.5 ),...
                  (  4.5 ,  0.5 ), (  5.0 ,  0.5 )
FUNCTION  DRPMT = (  0.0 ,  0.92), ( 10.0 ,  1.3 ), ( 20.0 ,  2.0 ),...
                  ( 30.0 ,  3.2 ), ( 40.0 ,  4.8 ), ( 50.0 ,  6.8 ),...
                  ( 60.0 ,  9.2 )
*                                                                            8100
*     ------------------------------------------------------------------
*
*     DR    = DEATH RATE (PEOPLE/YEAR)                                       4800
*     DRCM  = DEATH-RATE-FROM-CROWDING MULTIPLIER (DIMENSIONLESS)            4900
*     DRCMT = DEATH-RATE-FROM-CROWDING-MULTIPLIER TABLE                      5000
*     DRFM  = DEATH-RATE-FROM-FOOD MULTIPLIER (DIMENSIONLESS)                5100
*     DRFMT = DEATH-RATE-FROM-FOOD-MULTIPLIER TABLE　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　 　 　　 　　　　　　　5200
*            DRMM  = DEATH-RATE-FROM-MATERIAL MULTIPLIER (DIMENSIONLESS)            5300
*     DRMMT = DEATH-RATE-FROM-MATERIAL-MULTIPLIER TABLE                      5400
*     DRN   = DEATH RATE NORMAL (FRACTION/YEAR)                              5500
*     DRN1  = DEATH RATE NORMAL NO. 1 (FRACTION/YEAR)                        5600
*     DRNT3 = DRN1, IF(SWT3.LT.T)
*           = DRN1, IF(SWT3.EQ.T)
*           = DRN , IF(SWT3.GT.T)
*     DRPM  = DEATH-RATE-FROM-POLLUTION MULTIPLIER (DIMENSIONLESS)           5700
*     DRPMT = DEATH-RATE-FROM-POLLUTION-MULTIPLIER TABLE                     5800
*     SWT3  = SWITCH TIME NO. 3 FOR DRN (YEARS)                             11300
*                                                                            6700
*--------------------------------------------------------------------------------
* 3.4 CROWDING RATIO (CR)
*--------------------------------------------------------------------------------
*                                                                           20300
*     (SECTION 3.15 OF REFERENCE)
*                                                                           20350
*     THE CROWDING PATIO RELATES THE POPULATION TO THE AVAILABLE LAND AREA.
*     IT IS COMPUTED BY DIVIDING THE POPULATION (P) BY THE LAND AREA (LA) AND BY
*     THE 1970 POPULATION DENSITY NORMAL (PDN)
*
*     ------------------------------------------------------------------
*
      CR    =  P/(LA*PDN)                                                    3600
      CRX   =  LIMIT( 0.0, 5.0,    CR)                                        200
*
*     ------------------------------------------------------------------
*                                                                           10250
PARAMETER  LA     = 135.0000E+06, PDN   =  26.5000E+00
*
*     ------------------------------------------------------------------
*
*     CR    =  CROWDING RATIO (DIMENSIONLESS)                                4700
*     CRX   =  LIMITED VALUE OF "CR" (DIMENTIONLESS)
*           =  0.0, IF(CR.LT.0.0)
*           =  5.0, IF(CR.GT.5.0)
*           =  CR, IF(CR.GE.0.O.AND.CR.LE.5.0)
*     LA    =  LAND AREA (SQUARE KILOMETERS)                                 7200
*     PDN   =  POPULATION DENSITY NORMAL (PEOPLE/SQUARE KILOMETER)           8700
*                                                                           14650
*--------------------------------------------------------------------------------
* 4.  NATURAL RESOURCES (NR)
*--------------------------------------------------------------------------------
*                                                                           10550
*     (SECTION 3.6, 3.7, 3.8, 3.9, 3.42 OF REFERENCE)
*                                                                           20200
*     NATURAL RESOURCES (NR) ARE A SYSTEM LEVEL VARIABLE. THE ONLY RATE
*     OF FLOW IS THE OUTGOING USAGE RATE.  NATURAL RESOURCES (NR) IS
*     INTEGRATED WITH NEGATIVE VALUE OF NATURAL-RESOURCES-USAGE RATE (NRUR).
*     COMPUTED AT EACH TIME STEP BY SUBTRACTING THE USAGE RATE NRUR           100
*     MULTIPLIED BY THE TIME INTERVAL BETWEEN COMPUTATIONS.                   200
*
*     ------------------------------------------------------------------
*                                                                           20500
      NR    = INTGRL(NRI, —NRUR)                                             6400
      NREM  = AFGEN( NREMT, NRFRX)                                           6800
      NRFR  = NR/NPI                                                         6600
      NRFRX = LIMIT( 0.0, 1.0, NRFR)                                          850
      NRMM  = AFGEN( NRMMT, MSLXX)                                           6700
      NRUR  = P*NRUNT2*NRMM
      NRUNT2= FCNSW(SWT2-T,NRUN1,NRUN1,NRUN)
*
*     ------------------------------------------------------------------
*                                                                            4000
PARAMETER  NRUN  =   1.0000E+00, NRUN1 =   1.0000E+00,...                    6900
           SWT2  = 197.0000E+01                                              6950
*                                                                           10250
FUNCTION  NREMT = (  0.0 ,  0.0 ), (  0.25, 0.15), (  0.5 , 0.5 ),...
                  (  0.75,  O.85), (  1.0 , 1.0 )
FUNCTION  NRMMT = (  0.0 ,  0.0 ), (  1.0 , 1.0 ), (  2.0 , 1.8 ),...
                  (  3.0 ,  2.4 ), (  4.0 , 2.9 ), (  5.0 , 3.3 ),...
                  (  6.0 ,  3.6 ), (  7.0 , 3.8 ), (  8.0 , 3.9 ),...
                  (  9.0 ,  3.95), ( 10.0 , 4.0 )
*                                                                           10650
*     ------------------------------------------------------------------
*
*     NR    = NATURAL RESOURCES (NATURAL RESOURCE UNITS)                     7400
*     NREM  = NATURAL-RESOURCE-EXTRACTION MULTIPLIER (DIMENSIONLESS)         7500
*     NREMT = NATURAL-RESOURCE-EXTRACTION-MULTIPLIER TABLE                   7600
*     NRFR  = NATURAL-RESOURCE FRACTION REMAINING (DIMENSIONLESS)            7700
*     NRFRX = LIMITED VALUE OF "NRFR" (DIMENSIONLESS)
*           = 0.0, IF(NRFR.LT.0.0)
*           = 1.0, IF(NRFR.GT.1.0)
*           = NRFR, IF(NRFR.GE.0.O.AND.NRFR.LE.1.0)
*     NRMM  = NATURAL-RESOURCE-FROM-MATERIAL MULTIPLIER (DIMENSIONLESS)      7900
*     NRMMT = NATURAL-RESOURCE-FROM-MATERIAL-MULTIPLIER TABLE                8000
*     NRUN  = NATURAL-RESOURCE USAGE NORMAL                                  8100
*                  (NATURAL RESOURCE UNITS/PERSON/YEAR)                      8200
*     NRUN1 = NATURAL-RESOURCE USAGE NORMAL NO. 1                            8300
*                  (NATURAL RESOURCE UNITS/PERSON/YEAR)                      8400
*     NRUNT2= NRUN18 IF(SWT2.LT.T)
*           = NRUN1, IF(SWT2.EQ.T)
*           = NRUN , IF(SWT2.GT.T)
*     NRUR  = NATURAL-RESOURCE-USAGE RATE (NATURAL RESOURCE UNITS/YEAR)      8500
*     SWT2  = SWITCH TIME NO. 2 FOR NRUN (YEARS)                            11200
*
*--------------------------------------------------------------------------------
* 5.  CAPITAL INVESTMENT (CI)
*--------------------------------------------------------------------------------
* 5.1 CAPITAL INVESTMENT (CI)
*--------------------------------------------------------------------------------
*                                                                            6600
*     (SECTION 3.22, 3.23, 3.24, 3.25, 3.26, 3.27 OF REFERENCE)
*                                                                           14600
*     CAPITAL INVESTMENT (CI) IS ONE OF THE SYSTEM LEVELS. IT IS CREATED
*     BY ACCUMULATING THE CAPITAL INFLOW FROM CAPITAL-INVESTMENT              500
*     GENERATION (CIG) LESS THE OUTFLOW TO CAPITAL-INVESTMENT DISCARD (CID).
*                                                                            7150
*     ------------------------------------------------------------------
*
      CI    = INTGRL(CII,CIG-CID)                                            5100
      CIG   = P*CIGNT4*CIM
      CIGNT4= FCNSW(SWT4-T,CIGN1,CIGN1,CIGN)
      CID   = CIDNT5*CI
      CIDNT5= FCNSW(SWT5-T,CIDN1,CIDN1,CIDN)
      CIM   = AFGEN(  CIMT,  MSLX)                                           5700
      CIR   = CI/P                                                           5300
      CIRA  = CIR*CIAF/CIAFN                                                 5200
      CIRAX = LIMIT( 0.0, 6.0,  CIRA)                                         650
      CIRX  = LIMIT( 0.0, 5.0,   CIR)                                         950
*
*     ------------------------------------------------------------------
*　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　19500
PARAMETER  CIDN  =   0.0250E+00, CIDN1 =   0.0250E+00,...                    6100
           CIGN  =   0.0500E+00, CIGN1 =   0.0500E+00,...                    6000
           SWT4  = 197.0000E+01, SWT5  = 197.0000E+01                        6300
*                                                                            1150
FUNCTION  CIMT  = (  0.0 ,  0.1 ), (  1.0 ,  1.0 ), (  2.0 ,  1.8 ),...
                  (  3.0 ,  2.4 ), (  4.0 ,  2.8 ), (  5.0 ,  3.0 )
*                                                                            8450
*     ------------------------------------------------------------------
*                                                                            6150
*     CI     = CAPITAL INVESTMENT (CAPITAL UNITS)                            2300
*     CID    = CAPITAL-INVESTMENT DISCARD (CAPITAL UNITS/YEAR)               3100
*     CIDN   = CAPITAL-INVESTMENT DISCARD NORMAL (FRACTION/YEAR)             3200
*     CIDN1  = CAPITAL-INVESTMENT DISCARD NORMAL NO. 1 (FRACTION/YEAR)       3300
*     CIDNT5 = CIDN1, IF(SWT5.LT.T)
*            = CIDN1, IF(SWT5.EQ.T)
*            = CIDN , IF(SWT5.GT.T)
*     CIG    = CAPITAL-INVESTMENT GENERATION (CAPITAL UNITS/YEAR)            3400
*     CIGN   = CAPITAL-INVESTMENT GENERATION NORMAL                          3500
*                   (CAPITAL UNITS/PERSON/YEAR)                              3600
*     CIGN1  = CAPITAL-INVESTMENT GENERATION NORMAL NO. 1                    3700
*                   (CAPITAL UNITS/PERSON/YEAR)                              3800
*     CIGNT4 = CIGN1, IF(SWT4.LT.T)
*            = CIGN1, IF(SWT4.EQ.T)
*            = CIGN , IF(SWT4.GT.T)
*     CIM    = CAPITAL-INVESTMENT MULTIPLIER (DIMENSIONLESS)                 4000
*     CIMT   = CAPITAL-INVESTMENT-MULTIPLIER TABLE                           4100
*     CIR    = CAPITAL-INVESTMENT RATIO (CAPITAL UNITS/PERSON)               4400
*     CIRA   = CAPITAL-INVESTMENT RATIO IN AGRICULTURE                       4500
*                   (CAPITAL UNITS/PERSON)                                   4600
*     CIRAX  = LIMITED VALUE OF "CIRA" (CAPITAL UNITS/PERSON)
*            = 0.0, IF(CIRA.LT.0.0)
*            = 6.0, IF(CIRA.GT.6.0)
*            = CIRA,IF(CIRA.GE.0.0.AND.CIRA.LE.6.0)
*     CIRX   = LIMITED VALUE OF "CIR" (CAPITAL UNITS/PERSON)
*            = 0.0, IF(CIR.LT.0.0)
*            = 5.0, IF(CIR.GE.5.0)
*            = CIR, IF(CIR.GE.0.0.AND.CIR.LE.5.0)
*     SWT4   = SWITCH TIME NO. 4 FOR CIGN (YEARS)                           11400
*     SWT5   = SWITCH TIME NO. 5 FOR CIDN (YEARS)                           11500
*                                                                           22200
*--------------------------------------------------------------------------------
* 5.2 CAPITAL-INVESTMENT-IN-AGRICULTURE-FRACTION (CIAF)
*--------------------------------------------------------------------------------
*                                                                            6900
*     (SECTION 3.4, 3.5, 3.35, 3.43 OF REFERENCE)
*
*     CAPITAL-INVESTMENT-IN-AGRICULTURE-FRACTION (CIAF) IS A SYSTEM LEVEL
*     AND IT IS GENERATED AS A GRADUAL ADJUSTMENT
*     OF THE ACTUAL FRACTION OF CAPITAL IN AGRICULTURE AS IT MOVES            500
*     TOWARD THE FRACTION THAT IS CALLED FOR BY CURRENT CONDITIONS.  THE      600
*     TOTAL EFFECT OF COMPUTING (CIAF) IS TO GIVE FOOD A PRIORITY OVER
*     MATERIAL GOODS SO THAT THE MOST PRESSING NECESSITY OF LIFE GETS         800
*     PREFERRED CLAIM ON THE CAPITAL PLANT OF THE WORLD.                      900
*
*     ------------------------------------------------------------------
*
      CFIFR = AFGEN(CFIFRT,  FRXX)                                           5800
      CIAF  = INTGRL(CIAFI,(CFIFR*CIQR-CIAF)/CIAFT)                          5400
      CIQR  = AFGEN( CIQRT,    Q9)                                           5900
      ECIR  = CIR*(1.0-CIAF)*NREM/(1.0-CIAFN)                                3400
      MSL   = ECIR/ECIRN                                                     3300
      MSLX  = LIMIT( 0.0, 5.0,   MSL)                                         100
      MSLXX = LIMIT( 0.0,70.0,   MSL)                                         750
      Q9    = LIM!T( 0.0, 2.0, QLM/QLF)                                       550
*
*     ------------------------------------------------------------------
*
PARAMETER  CIAFN =   0.3000E+00, CIAFT =  15.0000E+00,...                    6200
           ECIRN =   1.0000E+00
*
FUNCTION  CFIFRT= (  0.0 ,  1.0 ), (  0.5 ,  0.6 ), (  1.0 ,  0.3 ),...
                  (  1.5 ,  0.15), (  2.0 ,  0.1 )
FUNCTION  CIQRT = (  0.0 ,  0.7 ), (  0.5 ,  0.8 ), (  1.0 ,  1.0 ),...
                  (  1.5 ,  0.5 ), (  2.0 ,  2.0 )
*                                                                            1500
*     ------------------------------------------------------------------
*
*     CFIFR = CAPITAL FRACTION INDICATED BY FOOD RATIO (DIMENSIONLESS)       2100
*     CFIFRT= CAPITAL-FRACTION-INDICATED-BY-FOOD-RAIO TABLE                  2200
*     CIAF  = CAPITAL-INVESTMENT-IN-AGRICULTURE FRACTION (DIMENSIONLESS)     2400
*     CIAFN = CAPITAL-INVESTMENT-IN-AGRICULTURE FRACTION NORMAL              2700
*                  (DIMENSIONLESS)                                           2800
*     CIAFT = CAPITAL-INVESTMENT-IN-AGRICULTURE-FRACTION ADJUSTMENT TIME     2900
*                  (YEARS)                                                   3000
*     CIQR  = CAPITAL-INVESTMENT-FROM-QUALITY RATIO (DIMENSIONLESS)          4200
*     CIQRT = CAPITAL-INVESTMENT-FROM-QUALITY-RATIO TABLE                    4300
*     ECIR  = EFFECTIVE-CAPITAL-INVESTMENT RATIO (CAPITAL UNITS/PERSON)      5900
*     ECIRN = EFFECTIVE-CAPITAL-INVESTMENT RATIO NORMAL                      6000
*     MSL   = MATERIAL STANDARD OF LIVING (DIMENSIONLESS)                    7300
*                  (CAPITAL UNITS/PERSON)                                    6050
*     MSLX  = LIMITED VALUE OF "MSL" (DIMENSIONLESS)
*           = 0.0, IF(MSL.LT.0.0)
*           = 5.0, IF(MSL.GT.5.0)
*           = MSL, IF(MSL.GE.3.3.AND.MSL.LE.5.0)
*     MSLXX = LIMITED VALUE OF "MSL" (DIMENSIONLESS)
*           = 0.0, IF(MSL.LT.0.0)
*           = 70.0, IF(MSL.GT.70.0)
*           = MSL, IF(MSL.GE.0.0.AND.MSL.LE.5.0)
*     Q9    = LIMITED VALUE OF "QLM/QLF" (DIMENSIONLESS)
*           = 0.0, IF(QLM/QLF.LT.0.0)
*           = 2.0, IF(QLM/QLF.GT.2.0)
*           = QLM/QLF, IF(QLM/QLF.GE.0.0 AND QLM/QLF.LE.2.0)
*
*--------------------------------------------------------------------------------
* 6.  POLLUTION (POL)
*--------------------------------------------------------------------------------
*
*     (SECTION 3.29, 3.30, 3.31, 3.32, 3.33, 3.34 OF REFERENCE)
*
*     POLLUTION (PCL) IS ONE OF THE FIVE SYSTEM LEVELS.  IT IS A POOL
*     WHICH POLLUTION GENERATION INCREASES AND WHICH POLLUTION                900
*     ABSORPTION EMPTIES.  POLLUTION (POL) REPRESENTS THE ACTIVE POLLUTION
*     IN THE ENVIRONMENT AS IT EXISTS AFTER GENERATION AND BEFORE             100
*     DISSIPATION INTO SOME HARMLESS AND INACTIVE FORM.                       200
*
*     ------------------------------------------------------------------
*
      POL   = INTGRL(POLI,POLG-POLA)                                         3900
      POLA  = POL/POLAT                                                      4100
      POLAT = AFGEN(POLATT, POLRX)                                           4200
      POLCM = AFGEN(POLCMT,  CIRX)                                           4300
      POLG  = P*POLNT6*POLCM
      POLNT6= FCNSW(SWT6-T,POLN1,POLN1,POLN)
      POLR  = PCL/POLS                                                       3800
      POLRX = LIMIT( 0.0,60.0,  POLR)                                         300
*
*     ------------------------------------------------------------------
*
PARAMETER  POLN  =   1.0000E+00, POLN1 =   1.0000E+00,...                    4400
           POLS  =   3.6000E+09, SWT6  = 197.0000E+0l                        4500
*
FUNCTION  POLATT= (  0.0 ,  0.6 ), ( 10.0 ,  2.5 ), ( 20.0 ,  5.0 ),...
                  ( 30.0 ,  8.0 ), ( 40.0 , 11.5 ), ( 50.0 , 15.5 ),...
                  ( 60.0 , 20.0 )
FUNCTION  POLCMT= (  0.0 ,  0.05), (  1.0 ,  1.0 ), (  2.0 ,  3.0 ),...
                  (  3.0 ,  5.4 ), (  4.0 ,  7.4 ), (  5.0 ,  8.0 )
*
*     ------------------------------------------------------------------
*
*     POL   = POLLUTION (POLLUTION UNITS)                                    8900
*     POLA  = POLLUTION ABSORPTION (POLLUTION UNITS/YEAR)                    9000
*     POLAT = POLLUTION-ABSORPTION TIME (YEARS)                              9100
*     POLATT= POLLUTION-ABSORPTION-TIME TABLE                                9200
*     POLCM = POLLUTION-FROM-CAPITAL MULTIPLIER (DIMENSIONLESS)              9300
*     POLCMT= POLLUTION-FROM-CAPITAL-MULTIPLIER TABLE                        9400
*     POLG  = POLLUTION GENERATION (POLLUTION UNITS/YEAR)                    9500
*     POLN  = POLLUTION NORMAL (POLLUTION UNITS/PERSON/YEAR)                 9700
*     POLN1 = POLLUTION NORMAL NO. 1 (POLLUTION UNITS/PERSON/YEAR)           9800
*     POLNT6= POLN1, IF(SWT6.LT.T)
*           = POLN1, IF(SWT6.EQ.T)
*           = POLN , IF(SWT6.GT.T)
*     POLR  = POLLUTION RATIO (DIMENSIONLESS)                                9900
*     POLRX = LIMITED VALUE OF "POLR" (DIMENSIONLESS)
*           = 0.0, IF(POLR.LT.0.0)
*           = 60.0. IF(POLR.GT.60.0)
*           = POLR, IF(POLR.GE.0.0 AND POLR.LE.60.0)
*     POLS  = POLLUTION STANDARD (POLLUTION UNITS)                          10000
*     SWT6  = SWITCH TIME NO. 6 FOR POLN (YEARS)                            11600
*
*--------------------------------------------------------------------------------
* 7.  FOOD RATIO (FR)
*--------------------------------------------------------------------------------
*
*     (SECTION 3.19, 3.20, 3.21, 3.28 OF REFERENCE)
*
*     THE FOOD PATIO GIVES THE FOOD PER CAPITA IN TERMS OF THE AVERAGE
*     FOR THE WORLD IN 1970. IT IS A DIMENSIONLESS RATIO OBTAINED BY DIVIDING
*     THE FOOD POTENTIAL FROM CAPITAL INVESTMENT (FPCI) BY THE 1970 FOOD 
*     NORMAL (FN) AND THEN MULTIPLYING BY THE INFLUENCES OF CROWDING AND
*     POLLUTION AND BY A FOOD COEFFICIENT (FC).
*
*     ------------------------------------------------------------------
*
      FR    = FPCI*FCM*FPM*FCT7/FN
      FCT7  = FCNSW(SWT7-T,FC1,FC1,FC)
      FCM   = AFGEN(  FCMT,   CRX)                                           2900
      FPCI  = AFGEN( FPCIT, CIRAX)                                           2800
      FPM   = AFGEN(  FPMT, POLRX)                                           3000
      FRX   = LIMIT( 0.0, 4.0,    FR)                                         000
      FRXX  = LIMIT( 0.0, 2.0,    FR)                                         400
*
*     ------------------------------------------------------------------
*
PARAMETER  FC1   =   1.0000E+00, FN    =   1.0000E+00,...
           FC    =   1.0000E+00, SWT7  = 197.0000E+01
*
FUNCTION   FCMT  = (  0.0 , 2.4 ), (  1.0 ,  1.0 ), (  2.0 ,  0.6 ),...
                   (  3.0 , 0.4 ), (  4.0 ,  0.3 ), (  5.0 ,  0.2 )
FUNCTION   FPCIT = (  0.0 , 0.5 ), (  1.0 ,  1.0 ), (  2.0 ,  1.4 ),...
                   (  3.0 , 1.7 ), (  4.0 ,  1.9 ), (  5.0 ,  2.05),...
                   (  6.0 , 2.2 )
FUNCTION   FPMT  = (  0.0 , 1.02), ( 10.0 ,  0.9 ), ( 20.0 ,  0.65),...
                   ( 30.0 , 0.35), ( 40.0 ,  0.2 ), ( 50.0 ,  0.1 ),...
                   ( 60.0 , 0.05)
*
*     ------------------------------------------------------------------
*
*     FC     = FOOD COEFFICIENT (DIMENSIONLESS)                              6150
*     FCM    = FOOD-FROM-CROWDING MULTIPLIER (DIMENSIONlESS)                 6350
*     FCMT   = FOOD-FROM-CROWDING-MULTIPLIER TABLE                           6450
*     FC1    = FOOD COEFFICIENT NO. 1 (DIMENSIONLESS)                        6250
*     FCT7   = FC1, IF(SWT7.LT.T)
*            = FC1, IF(SWT7.EQ.T)
*            = FC , IF(SWT7.GT.T)
*     FN     = FOOD NORMAL FOOD UNITS/PERSON/YEAR)                           6550
*     FPCI   = FOOD POTENTIAL FROM CAPITAL INVESTMENT                        6650
*                   (FOOD UNITS/PERSCN/YEAR)                                 6750
*     FPCIT  = FOOD-POTENTIAL-FROM-CAPITAL-INVESTMENT TABLE                  6850
*     FPM    = FOOD-FROM-POLLUTION MULTIPLIER (DIMENSIONLESS)                6950
*     FPMT   = FOOD-FROM-POLLUTION-MULTIPLIER TABLE                          7000
*     FR     = FOOD PATIO (DIMENSIONLESS)                                    7100
*     FRX    = LIMITED VALUE OF "FR" (DIMENSIONLESS)
*            = 0.0, IF(FR.LT.0.0)
*            = 4.0, IF(FR.GT.4.0)
*            = FR , IF(FR.GE.0.0.AND.FR.LE.4.0)
*     FRXX   = LIMITED VALUE OF "FR" (DIMENSIONLESS)
*            = 0.0. IF(FR.LT.0.0)
*            = 2.0, IF(FR.GT.2.0)
*            = FR, IF(FR.GE.0.0.AND.FR.LE.2.0)
*     SWT7   = SWITCH TIME NO. 7 FOR FC (YEARS)                             11700
*
*--------------------------------------------------------------------------------
* 8.  QUALITY OF LIFE (QL)
*--------------------------------------------------------------------------------
*
*     (SECTION 3.37, 3.38, 3.39, 3.40, 3.41 OF REFERENCE)
*                                                                            5860
*     QUALITY OF LIFE (QL) IS USED HERE AS A MEASURE OF PERFORMANCE OF THE
*     WORLD SYSTEM.  IT IS COMPUTED AS A QUALITY-OF-LIFE STANDARD (QLS)
*     MULTIPLIED BY FOUR MULTIPLIERS DERIVED FROM MATERIAL STANDARD OF        300
*     LIVING, CROWDING, FOOD, AND POLLUTION.                                  400
*
*     ------------------------------------------------------------------
*
      QL    = QLS*QLM*QLC*QLF*QLP                                            4600
      QLC   = AFGEN(  QLCT,   CRX)                                           4800
      QLF   = AFGEN(  QLFT,   FRX)                                           4900
      QLM   = AFGEN(  QLMT,  MSLX)                                           4700
      QLP   = AFGEN(  QLPT, POLRX)                                           4950
*
*     ------------------------------------------------------------------
*
PARAMETER  QLS   =   1.0000E+00                                              5000
*                                                                            1250
FUNCTION  QLCT  = (  0.0 , 2.0 ), (  0.5 , 1.3 ), (  1.0 , 1.0 ),...
                  (  1.5 , 0.75), (  2.0 , 0.55), (  2.5 , 0.45),...
                  (  3.0 , 0.38), (  3.5 , 0.3 ), (  4.0 , 0.25),...
                  (  4.5 , 0.22), (  5.0 , 0.2 )
FUNCTION  QLFT  = (  0.0 , 0.0 ), (  1.0 , 1.0 ), (  2.0 , 1.8 ),...
                  (  3.0 , 2.4 ), (  4.0 , 2.7 )
FUNCTION  QLMT  = (  0.0 , 0.2 ), (  1.0 , 1.0 ), (  2.0 , 1.7 ),...
                  (  3.0 , 2.3 ), (  4.0 , 2.7 ), (  5.0 , 2.9 )
FUNCTION  QLPT  = (  0.0 , 1.04), ( 10.0 , 0.85), ( 20.0 , 0.6 ),...
                  ( 30.0 , 0.3 ), ( 40.0 , 0.15). ( 50.0 , 0.05),...
                  ( 60.0 , 0.02)
*
*     ------------------------------------------------------------------
*
*     QL    = DUALITY OF LIFE (SATISFACTION UNITS)                          10100
*     QLC   = DUALITY OF LIFE FROM CROWDING (DIMENSIONLESS)                 10200
*     QLCT  = QUALITY-OF-LIFE-FROM-CROWDING TABLE                           10300
*     QLF   = QUALITY OF LIFE FROM FOOD (DIMENSIONLESS)                     10400
*     QLFT  = QUALITY-OF-LIFE-FROM-FOOD TABLE                               l0500
*     QLM   = QUALITY OF LIFE FROM MATERIAL (DIMENSIONLESS)                 10600
*     QLMT  = QUALITY-OF-LIFE-FROM-MATERIAL TABLE                           10700
*     QLP   = QUALITY OF LIFE FROM POLLUTION (DIMENSIONLESS)                10800
*     QLPT  = QUALITY-OF-LIFE-FROM-POLLUTION TABLE                          10900
*     QLS   = QUALITY-OF-LIFE STANDARD (SATISFACTION UNITS)                 11000
*                                                                            9950
*--------------------------------------------------------------------------------
* 9.  DEFINITIONS OF TERMS (ALPHABETICAL ORDER)
*--------------------------------------------------------------------------------
*                                                                           17800
*** A
*** B
*     BR    = BIRTH RATE (PEOPLE/YEAR)                                       1000
*     BRCM  = BIRTH-RATE-FROM-CROWDING MULTIPLIER (DIMENSIONLESS)            1100
*     BRCMT = BIRTH-RATE-FROM-CROWDING-MULTIPLIER TABLE                      1200
*     BRFM  = BIRTH-RATE-FROM-FOOD MULTIPLIER (DIMENSIONLESS)                1300
*     BRFMT = BIRTH-RATE-FROM-FOOD MULTIPLIER TABLE                          1400
*     BRMM  = BIRTH-RATE-FROM-MATERIAL MULTIPLIER (DIMENSIONLESS)            1500
*     BRMMT = BIRTH-RATE-FROM-MATERIAL-MULTIPLIER TABLE                      1600
*     BRN   = BIRTH RATE NORMAL (FRACTION/YEAR)                              1700
*     BRN1  = BIRTH RATE NORMAL NO. 1 (FRACTION/YEAR)                        1800
*     BBNT1 = BRN1, IF(SWT1.LT.T)
*           = BRN1, IF(SWT1.EQ.T)
*           = BRN , IF(SWT1.GT.T)
*     BRPM  = BIRTH-PATE-FROM-POLLUTION MULTIPLIER (DIMENSIONLESS)           1900
*     BRPMT = BIRTH-RATE-FROM-POLLUTION-MULTIPLIER TABLE                     2000
*** C
*     CFIFR = CAPITAL FRACTION INDICATED BY FOOD RATIO (DIMENSIONLESS)       2100
*     CFIFRT= CAPITAL-FRACTION-INDICATED-BY-FOOD-PATIO TABLE                 2200
*     CI    = CAPITAL INVESTMENT (CAPITAL UNITS)                             2300
*     CIAF  = CAPITAL-INVESTMENT-IN-AGRICULTURE FRACTION (DIMENSIONLESS)     2400
*     CIAFI = CAPITAL-INVESTMENT-IN-AGRICULTURE FRACTION,  INITIAL           2500
*                  (DIMENSIONLESS)                                           2600
*     CIAFN = CAPITAL-INVESTMENT-IN-AGRICULTURE FRACTION NORMAL              2700
*                  (DIMENSIONLESS)                                           2800
*     CIAFT = CAPITAL-INVESTMENT-IN-AGRICULTURE-FRACTION ADJUSTMENT TIME     2900
*                  (YEARS)                                                   3000
*     CID   = CAPITAL-INVESTMENT DISCARD (CAPITAL UNITS/YEAR)                3100
*     CIDN  = CAPITAL-INVESTMENT DISCARD NORMAL (FRACTION/YEAR)              3200
*     CIDN1 = CAPITAL-INVESTMENT DISCARD NORMAL NO. 1 (FRACTION/YEAR)        3300
*     CIDNT5= CIDN1, IF(SWT5.LT.T)
*           = CIDN1, IF(SWT5.EQ.T)
*           = CIDN , IF(SWT5.GT.T)
*     CIG   = CAPITAL-INVESTMENT GENERATION (CAPITAL UNITS/YEAR)             3400
*     CIGN  = CAPITAL-INVESTMENT GENERATION NORMAL                           3500
*                  (CAPITAL UNITS/PERSON/YEAR)                               3600
*     CIGN1 = CAPITAL-INVESTMENT GENERATION NORMAL NO. 1                     3700
*                  (CAPITAL UNITS/PERSON/YEAR)                               3800
*     CIGNT4= CIGN1, IF(SWT4.LT.T)
*           = CIGN1, IF(SWT4.EQ.T)
*           = CIGN , IF(SWT4.GT.T)
*     CII   = CAPITAL INVESTMENT, INITIAL (CAPITAL UNITS)                    3900
*     CIM   = CAPITAL-INVESTMENT MULTIPLIER (DIMENSIONLESS)                  4000
*     CIMT  = CAPITAL-INVESTMENT-MULTIPLIER TABLE                            4100
*     CIQR  = CAPITAL-INVESTMENT-FROM-QUALITY RATIO (DIMENSIONLESS)          4200
*     CIQRT = CAPITAL-INVESTMENT-FROM-QUALITY-RATIO TABLE                    4300
*     CIR   = CAPITAL-INVESTMENT RATIO (CAPITAL UNITS/PERSON)                4400
*     CIRX  = LIMITED VALUE OF "CIR" (CAPITAL UNITS/PERSON)
*           = 0.0, IF(CIR.LT.0.0)
*           = 5.0, IF(CIR.GE.5.0)
*           = CIR, IF(CIR.GE.0.0.AND.CIR.LE.5.O)
*     CIRA  = CAPITAL-INVESTMENT RATIO IN AGRICULTURE                        4500
*                  (CAPITAL UNITS/PERSON)                                    4600
*     CIRAX = LIMITED VALUE OF "CIRA" (CAPITAL UNITS/PEERSON)
            = 0.0, IF(CIRA.LT.0.0)
            = 6.0, IF(CIRA.GT.6.0)
*           = CIRA,IF(CIRA.GE.0.0.AND.CIRA.LE.6.0)
*     CR    = CROWDING RATIO (DIMENSIONLESS)                                 4700
*     CRX   = LIMITED VALUE OF "CR" (DIMENSIONLESS)
*           = 0.0, IF(CR.LT.0.0)
*           = 5.0, IF(CR.GT.5.0)
*           = CR, IF(CR.GE.0.0.AND.CR.LE.5.0)
*** D
*     DR    = DEATH RATE (PEOPLE/YEAR)                                       4800
*     DRCM  = DEATH-RATE-FROM-CROWDING MULTIPLIER (DIMENSIONLESS)            4900
*     DRCMT = DEATH-RATE-FROM-CROWDING-MULTIPLIER TABLE                      5000
*     DRFM  = DEATH-RATE-FROM-FOOD MULTIPLIER (DIMENSIONLESS)                5100
*     DRFMT = DEATH-RATE-FROM-FOOD-MULTIPLIER TABLE                          5200
*     DRMM  = DEATH-RATE-FROM-MATERIAL MULTIPLIER (DIMENSIONLESS)            5300
*     DRMMT = DEATH-RATE-FROM-MATERIAL-MULTIPLIER TABLE                      5400
*     DRN   = DEATH RATE NORMAL (FRACTION/YEAR)                              5500
*     DRN1  = DEATH RATE NORMAL NO. 1 (FRACTION/YEAR)                        5600
*     DRNT3 = DRN1, IF(SWT3.LT.T)
*           = DRN1, IF(SWT3.EQ.T)
*           = DRN , IF(SWT3.GT.T)
*     DRPM  = DEATH-RATE-FROM-POLLUTION MULTIPLIER (DIMENSIONLESS)           5700
*     DRPMT = DEATH-RATE-FROM-POLLUTION-MULTIPLIER TABLE                     5800
*** E
*     ECIR  = EFFECTIVE-CAPITAL-INVESTMENT RATIO (CAPITAL UNITS/PERSON)      5900
*     ECIRN = EFFECTIVE-CAPITAL-INVESTMENT RATIO NORMAL                      6000
*                  (CAPITAL UNITS/PERSON)                                    6050
*** F
*     FC    = FOOD COEFFICIENT (DIMENSIONLESS)                               6150
*     FC1   = FOOD COEFFICIENT NO. 1 (DIMENSIONLESS)                         6250
*     FCM   = FOOD-FROM-CROWDING MULTIPLIER (DIMENSIONLESS)                  6350
*     FCMT  = FOOD-FROM-CROWDING-MULTIPLIER TABLE                            6450
*     FN    = FOOD NORMAL (FOOD UNITS/PEPSON/YEAR)                           6550
*     FPCI  = FOOD POTENTIAL FROM CAPITAL INVESTMENT                         6650
*                  (FOOD UNITS/PERSO/YEAR)                                   5750
*     FPCIT = FOOD-POTENTIAL-FROM-CAPITAL-INVESTMENT TABLE                   6850
*     FPM   = FOOD-FROM-POLLUTION MULTIPLIER (DIMENSIONLESS)                 6950
*     FPMT  = FOOD-FROM-POLLUTION-MULTIPLIER TABLE                           7000
*     FR    = FOOD PATIO (DIMENSIONLESS)                                     7100
*     FRX   = LIMITED VALUE OF "FR" (DIMENSIONLESS)
*           = 0.0, IF(FR.LT.0,0)
*           = 4.0, IF(FR.GT.4.0)
*           = FR , IF(FR.GE.0.0.AND.FR.LE.4.0)
*     FRXX  = LIMITED VALUE OF "FR" (DIMENSIONLESS)
*           = 0.0, IF(FR.LT.0.0)
*           = 2.0, IF(FR.GT.2.0)
*           = FR, IF(FR.GE.0.0.AND.FR.LE.2.0)
*** G
*** H
*** I
*** J
*** K
*** L
*     LA    = LAND AREA (SQUARE KILOMETERS)                                  7200
*** M
*     MSL   = MATERIAL STANDARD OF LIVING (DIMENSIONLESS)                    7300
*     MSLX  = LIMITED VALUE OF "MSL" (DIMENSIONLESS)
*           = 0.0, IF(MSL.LT.0.0)
*           = 5.0, IF(MSL.GT.5.0)
*           = MSL, IF(MSL.GE.3.3.AND.MSL.LE.5.0)
*     MSLXX = LIMITED VALUE OF "MSL" (DIMENSIONLESS)
*           = 0.0, IF(MSL.LT.0.0)
*           = 70.0, IF(MSL.GT.70.0)
*           = MSL, IF(MSL.GE.0.0.AND.MSL.LE.5.0)
*** N
*     NR    = NATURAL RESOURCES (NATURAL RESOURCE UNITS)                     7400
*     NREM  = NATURAL-RESOURCE-EXTRACTION MULTIPLIER (DIMENSIONLESS)         7500
*     NREMT = NATURAL-RESOURCE-EXTRACTION-MULTIPLIER TABLE                   7600
*     NRFR  = NATURAL-RESOURCE FRACTION REMAINING (DIMENSIONLESS)            7700
*     NRFRX = LIMITED VALUE OF "NRFR" (DIMENSIONLESS)
*           = 0.0, IF(NRFR.LT.1.0)
*           = 1.0, IF(NRFR.GT.1.0)
*           = NRFR, IF(NRPR.GE.0.0.AND.NRFR.LE.1.0)
*     NRI   = NATURAL RESOURCE, INITIAL (NATURAL RESOURCE UNITS)             7800
*     NRMM  = NATURAL-RESOURCE-FROM-MATERIAL MULTIPLIER (DIMENSIONLESS)      7900
*     NRMMT = NATURAL-RESOURCE-FROM-MATERIAL-MULTIPLIER TABLE                8000
*     NRUN  = NATURAL-RESOURCE USAGE NORMAL                                  8100
*                  (NATURAL RESOURCE UNITS/PERSON/YEAR)                      8200
*     NRUN1 = NATURAL-RESOURCE USAGE NORMAL NO. 1                            8300
*                  (NATURAL RESOURCE UNITS/PERSON/YEAR)                      8400
*     NRUNT2= NRUN18 IF(SWT2.LT.T)
*           = NRUN1, IF(SWY2.EQ.T)
*           = NRUN , IF(SWT2.GT.T)
*     NRUR  = NATURAL-RESOURCE-USAGE RATE (NATURAL RESOURCE UNITS/YEAR)      8500
*** O
*** P
*     P     = POPULATION (PEOPLE)                                            8600
*     PDN   = POPULATION DENSITY NORMAL (PEOPLE/SQUARE KILOMETER)            8700
*     PI    = POPULATION, INITIAL (PEOPLE)                                   8800
*     POL   = POLLUTION (POLLUTION UNITS)                                    8900
*     POLA  = POLLUTION ABSORPTION (POLLUTION UNITS/YEAR)                    9000
*     POLAT = POLLUTION-ABSORPTION TIME (YEARS)                              9100
*     POLATT= POLLUTION-ABSORPTION-TIME TABLE                                9200
*     POLCM = POLLUTION-FROM-CAPITAL MULTIPLIER (DIMENSIONLESS)              9300
*     POLCMT= POLLUTION-FROM-CAPITAL-MULTIPLIER TABLE                        9400
*     POLG  = POLLUTION GENERATION (POLLUTION UNITS/YEAR)                    9500
*     POLI  = POLLUTION, INITIAL (POLLUTION UNITS)                           9600
*     POLN  = POLLUTION NORMAL (POLLUTION UNITS/PERSON/YEAR)                 9700
*     POLN1 = POLLUTION NORMAL NO. 1 (POLLUTION UNITS/PERSON/YEAR)           9800
*     POLNT6= POLN1, IF(SWT6.LT.T)
*           = POLN1, IF(SWT6.EQ.T)
*           = POLN , IF(SWT6.GT.T)
*     POLR  = POLLUTION RATIO (DIMENSIONLESS)                                9900
*     POLRX = LIMITED VALUE OF "POLR" (DIMENSIONLESS)
*           = 0.0, IF(POLR.LT.0,0)
*           = 60.0, IF(POLR.GT.60.0)
*           = POLR, IF(POLR.GE.0.0 AND POLR.LE.60.0)
*     POLS  = POLLUTION STANDARD (POLLUTION UNITS)                          10000
*** Q
*     Q9    = LIMITED VALUE OF "QLM/QLF" (DIMENsIONLESS)
*           = 0.0, IF(QLM/QLF.LT.0.0)
*           = 2.0, IF(QLM/QLF.GT.2.0)
*           = QLM/QLF, IF(QLM/QLF.GE.0.0 AND QLM/QLF.LE.2.0)
*     QL    = QUALITY OF LIFE (SATISFACTION UNITS)                          10100
*     QLC   = QUALITY OF LIFE FROM CROWDING (DIMENSIONLESS)                 10200
*     QLCT  = QUALITY-OF-LIFE-FROM-CROWDING TABLE                           10300
*     QLF   = QUALITY OF LIFE FROM FOOD (DIMENSIONLESS)                     10400
*     QLFT  = QUALITY-OF-LIFE-FROM-FOOD TABLE                               10500
*     QLM   = QUALITY OF LIFE FROM MATERIAL (DIMENSIONLESS)                 10600
*     QLMT  = QUALITY-OF-LIFE-FROM-MATERIAL TABLE                           10700
*     QLP   = QUALITY OF LIFE FROM POLLUTION (DIMENSIONLESS)                10800
*     QLPT  = QUALITY-OF-LIFE-FROM-POLLUTION TABLE                          10900
*     QLS   = QUALITY-OF-LIFE STANDARD (SATISFACTION UNITS)                 11000
*** R
*** S
*     SWT1  = SWITCH TIME NO. 1 FOR BRN (YEARS)                             11100
*     SWT2  = SWITCH TIME NO. 2 FOR NRUN (YEARS)                            11200
*     SWT3  = SWITCH TIME NO. 3 FOR DRN (YEARS)                             11300
*     SWT4  = SWITCH TIME NO. 4 FOR CIGN (YEARS)                            11400
*     SWT5  = SWITCH TIME NO. 5 FOR CIDN (YEARS)                            11500
*     SWT6  = SWITCH TIME NO. 6 FOR POLN (YEARS)                            11600
*     SWT7  = SWITCH TIME NO. 7 FOR FC (YEARS)                              11700
*** T
*     T     = CALENDAR TIME (YEARS)                                         11800
*** U
*** V
*** W
*** X
*** Y
*** Z
*                                                                           11650
*********************************************************************************
*********************************************************************************
TERMINAL SEGMENT
*********************************************************************************
*********************************************************************************
*                                                                           16200
*--------------------------------------------------------------------------------
* 10. CONTROL OF COMPUTER EXECUTION
*--------------------------------------------------------------------------------
*                                                                           23450
TIMER T    = 1900.0,  FINTIM = 2260.0,  DELT  = 0.4
*                                                                            1350
METHOD RECT                                                                 23550
*                                                                            1050
*     ------------------------------------------------------------------
*                                                                            6010
*     T     = TIME TO START SIMULATION AND OUTPUT RUN (YEARS)
*     FINTIM= FINAL TIME OF SIMULATION RUN (YEARS)
*     DELT  = TIME INTERVAL OF SIMULATION RUN (YEARS)
*     RECT  = RECTANGULAR INTEGRATION METHOD
*                                                                           24000
*--------------------------------------------------------------------------------
* 11. CONTROL OF COMPUTATIONAL OUTPUT
*--------------------------------------------------------------------------------
*
TIMER OUTDEL = 4.0                                                          23300
OUTPUT P,POLR,CI,QL,NR                                                      24650
PAGE  SYMBOL=(P,2,C,Q,N)
LABEL CSMP-III SIMULTATION OF WORLD DYNAMICS-2
LABEL P     = POPULATION,      POLR  = POLLUTION,
LABEL CI    = CAPITAL INVESTMENT,        QL    = QUALITY OF LIFE,
LABEL NR    = NATURAL RESOURCES
RANGE P,POLR,CI,QL,NR                                                       24850
*
*     ------------------------------------------------------------------
*
*     OUTDEL= TIME INTERVAL OF COMPUTER OUTPUT (YEARS)
*     OUTPUT= COMMAND TO PLOT VARIABLES WHICH FOLLOW
*     PAGE  = COMMAND TO SYMBOLIZE THE OUTPUT VARIABLES
*     LABEL = HEADING AT THE TOP OF COMPUTER OUTPUT
*     RANGE = COMMAND TO LIST MAX. AND MIN. OF VARIABLES WHICH FOLLOW,
*             DURING SIMULATION RUN
*
*********************************************************************************
*
END

$$$C0NTINUOUS SYSTEM MODELING PROGRAM  III   V1MO   TRANSLATOR OUTPUT$$$
*
*     APPENDIX
*                                                                           10350
*********************************************************************************
*********************************************************************************
*
* A-1 THE FOLLOWING IS THE PLOTTING SEGMENT OF AFGEN TABLES (l)
*
LABEL CSMP-111 SIMULATION OF WORLD DYNAMICS-2     AFGEN TABLES (1)
*                                                                           22400
RENAME   TIME =     XX, FINTIM =  FINXX                                      3200
*
*********************************************************************************
*
***** FUNCTION GENERATION DATA
*                                                                           23000
FUNCTION BRCMT  = (  0.0 ,  1.05), (  1.0 ,  1.0 ), (  2.0 ,  0.9 ),...
                  (  3.0 ,  0.7 ), (  4.0 ,  0.6 ), (  5.0 ,  0.55),...
                  (  6.0 ,  0.55)
FUNCTION BRFMT  = (  0.0 ,  0.0 ), (  1.0 ,  1.0 ), (  2.0 ,  1.6 ),...
                  (  3.0 ,  1.9 ), (  4.0 ,  2.0 ), (  5.0 ,  2.0 )
FUNCTION BRMMT  = (  0.0 ,  1.2 ), (  1.0 ,  1.0 ), (  2.0 ,  0.85),...
                  (  3.0 ,  0.75), (  4.0 ,  0.7 ), (  5.0 ,  0.7 )
FUNCTION CFIFRT = (  0.0 ,  1.0 ), (  0.5 ,  0.6 ), (  1.0 ,  0.3 ),...
                  (  1.5 ,  0.15), (  2.0 ,  0.1 ), (  2.5 ,  0.1 )
FUNCTION CIMT   = (  0.0 ,  0.1 ), (  1.0 ,  1.0 ), (  2.0 ,  1.8 ),...
                  (  3.0 ,  2.4 ), (  4.0 ,  2.8 ), (  5.0 ,  3.0 ),...
                  (  6.0 ,  3.0 )
FUNCTION CIQRT  = (  0.0 ,  0.7 ), (  0.5 ,  0.8 ), (  1.0 ,  1.0 ),...
                  (  1.5 ,  1.5 ), (  2.0 ,  2.0 ), (  2.5 ,  2.0 )
FUNCTION DRCMT  = (  0.0 ,  0.9 ), (  1.0 ,  1.0 ), (  2.0 ,  1.2 ),...
                  (  3.0 ,  1.5 ), (  4.0 ,  1.9 ), (  5.0 ,  3.0 ),...
                  (  6.0 ,  3.0 )
FUNCTION DRFMT  = (  0.0 , 30.0 ), (  0.25,  3.0 ), (  0.5 ,  2.0 ),...
                  (  0.75,  1.4 ), (  1.0 ,  1.0 ), (  1.25,  0.7 ),...
                  (  1.5 ,  0.6 ), (  1.75,  0.5 ), (  2.0 ,  0.5 )
FUNCTION DRMMT  = (  0.0 ,  3.0 ), (  0.5 ,  1.8 ), (  1.0 ,  1.0 ),...
                  (  1.5 ,  0.8 ), (  2.0 ,  0.7 ), (  2.5 ,  0.6 ),...
                  (  3.0 ,  0.53), (  3.5 ,  0.5 ), (  4.0 ,  0.5 ),...
                  (  4.5 ,  0.5 ), (  5.0 ,  0.5 )
FUNCTION FCMT   = (  0.0 ,  2.4 ), (  1.0 ,  1.0 ), (  2.0 ,  0.6 ),...
                  (  3.0 ,  0.4 ), (  4.0 ,  0.3 ), (  5.0 ,  0.2 ),...
                  (  6.0 ,  0.2 )
FUNCTION FPCIT  = (  0.0 ,  0.5 ), (  1.0 ,  1.0 ), (  2.0 ,  1.4 ),...
                  (  3.0 ,  1.7 ), (  4.0 ,  1.9 ), (  5.0 ,  2.05),...
                  (  6.0 ,  2.2 )
FUNCTION NREMT  = (  0.0 ,  0.0 ), (  0.25,  0.15), (  0.5 ,  0.5 ),...
                  (  0.75,  0.85), (  1.0 ,  1.0 ), (  1.25,  1.0 ),...
FUNCTION PCLCMT = (  0.0 ,  0.05), (  1.0 ,  1.0 ), (  2.0 ,  3.0 ),...
                  (  3.0 ,  5.4 ), (  4.0 ,  7.4 ), (  5.0 ,  8.0 ),...
                  (  6.0 ,  8.0 )
FUNCTION QLCT   = (  0.0 ,  2.0 ), (  0.5 ,  1.3 ), (  1.0 ,  1.0 ),...
                  (  1.5 ,  0.75), (  2.0 ,  0.55), (  2.5 ,  0.45),...
                  (  3.0 ,  0.38), (  3.5 ,  0.3 ), (  4.0 ,  0.25),...
                  (  4.5 ,  0.22), (  5.0 ,  0.2 ), (  5.5 ,  0.2 )
FUNCTION QLFT   = (  0.0 ,  0.0 ), (  1.0 ,  1.0 ), (  2.0 ,  1.8 ),...
                  (  3.0 ,  2.4 ), (  4.0 ,  2.7 ), (  5.0 ,  2.7 )
FUNCTION QLMT   = (  0.0 ,  0.2 ), (  1.0 ,  1.0 ), (  2.0 ,  1.7 ),...
                  (  3.0 ,  2.3 ), (  4.0 ,  2.7 ), (  5.0 ,  2.9 ),...
                  (  6.0 ,  2.9 )
*                                                                            2750
*********************************************************************************
*
      BRCM  = AFGEN( BRCMT,    XX)                                           1000
      BRFM  = AFGEN( BRFMT,    XX)                                           1100
      BRMM  = AFGEN( BRMMT,    XX)                                           1200
      CFIFR = AFGEN(CFIFRT,    XX)                                           1400
      CIM   = AFGEN(  CIMT,    XX)                                           1500
      CIQR  = AFGEN( CIQRT,    XX)                                           1600
      DRCM  = AFGEN( DRCMT,    XX)                                           1700
      DRFM  = AFGEN( DRFMT,    Xx)                                           1800
      DRMM  = AFGEN( DRMMT,    XX)                                           1900
      FCM   = AFGEN(  FCMT,    XX)                                           2100
      FPCI  = AFGEN( FPCIT,    XX)                                           2200
      NREM  = APGEN( NREMT,    XX)                                           2400
      POLCM = AFGEN(POLCMT,    XX)                                           2700
      QLC   = AFGEN(  QLCT,    XX)                                           2800
      QLF   = AFGEN(  QLFT,    XX)                                           2900
      QLM   = AFGEN(  QLMT,    XX)                                           3000
*                                                                            2550
*********************************************************************************
*
TIMER   FINXX =   6.0 , OUTDEL =   0.25,    DELT =   0.25                    3300
*                                                                            2350
OUTPUT   BRCM,   BRFM,   BRMM                                                3800
PAGE   SYMBOL = (C,F,M)                                                      3900
LABEL  BIRTH-RATE-FROM-CROWDING-MULTIPLIER TABLE (BRCMT)
LABEL  BIRTH-PATE-FROM-FOOD-MULTIPLIER TABLE (BRFMT)
LABEL  BIRTH-RATE-FROM-FOOD-MULTIPLIER TABLE (BRMMT)
*                                                                            2150
OUTPUT  CFIFR,    CIM,   CIQR                                                4000
PAGE   SYMBOL = (F,M,Q)                                                      4100
LABEL  CAPITAL-FRACTION-INDICATED-BY-FOOD-RATIO TABLE (CFIERT)
LABEL  CAPITAL-INVESTMENT-MULTIPLIER TABLE (CIMT)
LABEL  CAPITAL-INVESTMENT-FROM-QUALITY RATIO TABLE (CIQRT)
*
OUTPUT   DRCM,   DRFM,   DRMM                                                4500
PAGE   SYMBOL = (C,F,M)                                                      4600
LABEL  DEATH-RATE-FROM-CROWDING-MULTIPLIER TABLE (DRCMT)
LABEL  DEATH-RATE-FROM-FOOD-MULTIPLIER TABLE (DRFMT)
LABEL  DEATH-RATE-FROM-MATERIAL-MULTIPLIER TABLE (DRMMT)
*
OUTPUT    FCM,   FPCI                                                        5000
PAGE   SYMBOL = (C,P)                                                        5100
LABEL  FOOD-FROM-CROWDING-MULTIPLIER TABLE (FCMT)
LABEL  FOOD-POTENTIAL-FROM-CAPITAL-INVESTMENT TABLE (FPCIT)
*
OUTPUT    QLC,    QLF,    QLM                                                5400
PAGE   SYMBOL = (C,F.M)                                                      5500
LABEL  QUALITY-OF-LIFE-FROM-CROWDING TABLE (QLCT)
LABEL  QUALITY-OF-LIFE-FROM-FOOD TABLE (QLFT)
LABEL  QUALITY-OE-LIFL-RROM-MATERIAL TABLE (QLMT)
*                                                                           12900
OUTPUT  POLCM,   NREM                                                        5900
PAGE   SYMBOL = (P,N)                                                        6000
LABEL  POLLUTION-FROM-CAPITAL-MULTIPLIER TABLE (POLCMT)
LABEL  NATURAL-RESOURCE-EXTRACTION-MULTIPLIER (NREMT)
*
*********************************************************************************
*                                                                            1700
END

$$$CONTINUOUS SYSTEM MODELING PROGRAM  III   V1MO   TRANSLATOR OUTPUT$$S
*
*********************************************************************************
*********************************************************************************
* A-2 THE FOLLOWING IS THE PLOTTING SEGMENT OF AFGEN TABLES (2)
*
LABEL CSMP-III SIMULATION OF WORLD DYNAMICS-2     AFGEN TABLES (2)
*
RENAME   TIME =     XX, FINTIM =  FINXX                                      3200
*
*********************************************************************************
*                                                                            4200
***** FUNCTION GENERATION DATA
*
FUNCTION  BRPMT = (  0.0 , 1.02), ( 10.0 ,  0.9 ), ( 20.0 ,  0.7 ),...
                  ( 30.0 , 0.4 ), ( 40.0 ,  0.25), ( 50.0 ,  0.15),...
                  ( 60.0 , 0.1 )
FUNCTION  DRPMT = (  0.0 , 0.92), ( 10.0 ,  1.3 ), ( 20.0 ,  2.0 ),...
                  ( 30.0 , 3.2 ), ( 40.0 ,  4.8 ), ( 50.0 ,  6.8 ),...
                  ( 60.0 , 9.2 )
FUNCTION  FPMT  = (  0.0 , 1.02), ( 10.0 ,  0.9 ), ( 20.0 ,  0.65),...
                  ( 30.0 , 0.35), ( 40.0 ,  0.2 ), ( 50.0 ,  0.1 ),...
                  ( 60.0 , 0.05)
FUNCTION  NRMMT = (  0.0 , 0.0 ), (  1.0 ,  1.0 ), (  2.0 ,  1.8 ),...
                  (  3.0 , 2.4 ), (  4.0 ,  2.9 ), (  5.0 ,  3.3 ),...
                  (  6.0 , 3.6 ), (  7.0 ,  3.8 ), (  8.0 ,  3.9 ),...
                  (  9.0 , 3.95), ( 10.0 ,  4.0 ), ( 11.0 ,  4.0 )
FUNCTION  POLATT= (  0.0 , 0.6 ), ( 10.0 ,  2.5 ), ( 20.0 ,  5.0 ),...
                  ( 30.0 , 8.0 ), ( 40.0 , 11.5 ), ( 50.0 , 15.5 ),...
                  ( 60.0 , 20.0)
FUNCTION  QLPT =  (  0.0 , 1.04), ( 10.0 ,  0.85), ( 20.0 ,  0.6 ),...
                  ( 30.0 , 0.3 ), ( 40.0 ,  0.15), ( 50.0 ,  0.05),...
                  ( 60.0 , 0.02)
*
*********************************************************************************
*                                                                            4500
      BRPM  = AFGEN( BRPMT, XX)                                              1300
      DRPM  = AFGEN( DRPMT, XX)                                              2000
      FPM   = AFGEN(  FPMT, XX)                                              2300
      NRMM  = AFGEN( NRMMT, XX)                                              2500
      POLAT = AFGEN(POLATT, XX)                                              2600
      QLP   = AFGEN(  QLPT, XX)                                              3100
*
*********************************************************************************
*
TIMER   FINXX =  60.0 , OUTDEL = 1.0 ,    DELT =   1.0                       3400
*
OUTPUT   BRPM,   DRPM                                                        6300
PAGE   SYMBOL = (B,D)                                                        6400
LABEL  BIRTH-RATE-FROM-POLLUTION MULTIPLIER TABLE (BRPMT)
LABEL  DEATH-RATE-FROM-POLLUTION MULTIPLIER TABLE (DRPMT)
*
OUTPUT    FPM,   NPMM                                                        6700
PAGE   SYMBOL = (F,N)                                                        6800
LABEL  FOOD-FROM-POLLUTION-MULTIPLIER TABLE (FPMT)
LABEL  NATURAL-RESOURCE-FROM-MATERIAL-MULTIPLIER TABLE (NRMMT)
*
OUTPUT  POLAT,    QLP                                                        7100
PAGE   SYMBOL = (P,Q)                                                        7200
LABEL  POLLUTION-ABSORPTION-TIME TABLE (POLATT)
LABEL  QUALITY-OF-LIFE-FROM-POLLUTION TABLE (QLPT)
*
*********************************************************************************
*
END                                                                         24900
STOP                                                                        24950